In Perl, how can I capture a string of digits from a string containing carriage returns and line feeds?

Question

I need to extract the text (characters and numbers) from a multiline string. Everything I have tried does not strip out the line feeds/carriage returns.

Here is the string in question:

"\r\n        50145395\r\n    "

In HEX it is: 0D 0A 20 20 20 20 20 20 20 20 35 30 31 34 35 33 39 35 0D 0A 20 20 20 20

I have tried the following:

$sitename =~ m/(\d+)/g;  
$sitename = $1;

and

$sitename =~ s/^\D+//g;  
$sitename =~ s/\D+$//g;

and

$sitename =~ s/^\s+//g;  
$sitename =~ s/\s+$//g;

In all cases I cannot get rid of any of the unwanted characters. I have run this in cygwin perl and Strawberry perl.

Thanks.

Answer 1

Capturing match in list context returns captured strings:

#!/usr/bin/perl

use strict; use warnings;

my $s = join('', map chr(hex), qw(
    0D 0A 20 20 20 20 20 20 20 20 35 30 
    31 34 35 33 39 35 0D 0A 20 20 20 20
));

my ($x) = $s =~ /([A-Za-z0-9]+)/;

print "'$x'\n";

Output:

C:\Temp> uio
'50145395'

Answer 2

I'm not sure that you need, but here is code extracting all words from string

my @words = ( $sitename =~ m/(\w+)/g );

It can be also done with split. But you need to use spaces now:

my @words = split( m/\s+/, $sitename );

Answer 3

The obvious one I didn't see in your post:

$sitename =~ s/\D//g;

This removes all non-digits. To remove anything but word characters, you could:

$sitename =~ s/\W//g;

There's no need for ^ or $ if your intention is to replace every non-digit. Also, you can replace one character at a time if you use the global g option; no need to match more than one digit with \d+.

Answer 4

Edit: My solution was incorrect; please instead pay attention to Sinan Ünür's solution.

Answer 5

In the past I have done something like:

my $newline = chr(13) . chr(10);

$data =~ s/$newline/ /g;

You can check out other ascii character codes at: http://www.asciitable.com./

use strict;

my $newline = chr(13);
my $newline2 = chr(10);

my $words = "\r\n        50145395\r\n    ";

foreach my $char (split //, $words) {
 my $val=ord($char);    
 print "->$char<- ($val)\n";
}

print "$words\n";

$words =~ s/$newline//g;
$words =~ s/$newline2//g;
$words =~ s/[ ]+//g;

foreach my $char (split //, $words) {
 my $val=ord($char);    
 print "->$char<- ($val)\n";
}

print "$words\n";

Answer 6

Do you want to remove only newlines and carriage returns? If so, this is what you want:

$sitename =~ s/[\r\n]//g;

If you want to remove all whitespace, not just newlines and linefeeds, use this instead:

$sitename =~ s/\s//g;

Answer 7

$x = <<END;
this is a multiline 
string. this is a multiline
string.
END

$x =~ s/\r?\n?//g;
print $x;