ansaurus

Question

DotNetNuke + XPath = Custom navigation menu

Answer 1

+1 A:

The following assumes that there can only be one selected node in the input:

<xsl:stylesheet 
  version="1.0" 
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
  <xsl:template match="/">
    <div class="SideMenu">
      <!-- select all the siblings of the selected node -->
      <xsl:apply-templates select="//node[@selected=1]/../node" />
    </div>
  </xsl:template>

  <!-- nodes are turned into a <div> with some descriptive text -->
  <xsl:template match="node">
    <div>
      <xsl:value-of select="concat('[ ', @text, ': ', ' ]')" />
    </div>
  </xsl:template>

</xsl:stylesheet>

Output for your sample XML:

<div class="SideMenu">
  <div>[ Standard options: ]</div>
  <div>[ Specifying filenames: ]</div>
  <div>[ XML format: ]</div>
  <div>[ Creating custom templates: ]</div>
</div>

A nested menu is easily created, but admittedly I'm not really sure what you want. If you post the desired output, I can see to it.

Tomalak 2009-12-21 13:01:59

Answer 2

A:

Hi Peter,

If you can post the actual output you'd expect to be seeing then it would help, but I think you might want something like this:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;
  <xsl:template match="root">
    <div class="SideMenu">
      <!-- Loop through level 1 nodes -->
      <xsl:apply-templates select="//node[@depth=1]" mode="general" />
    </div>
  </xsl:template>

  <xsl:template match="node" mode="general">
    <xsl:choose>
      <!-- If the currently selected node, show all siblings -->
      <xsl:when test="@selected=1">
        <xsl:apply-templates select="../node" mode="only" />
      </xsl:when>
      <!-- Otherwise show just this node -->
      <xsl:otherwise>
        <xsl:apply-templates select="." mode="only" />
      </xsl:otherwise>
    </xsl:choose>
    <!-- Follow the breadcrumb down towards the currently selected node -->
    <xsl:apply-templates select="node[@breadcrumb=1]" mode="general" />
  </xsl:template>

  <xsl:template match="node" mode="only">
    <div>
      [ <xsl:value-of select="@text"/>: <xsl:value-of select="@depth"/> ]
    </div>
  </xsl:template>
</xsl:stylesheet>

If that doesn't give you what you want, feel free to drop a question on the DNNDoneRight forums, that's what they're there for!

MarkXA 2009-12-21 14:43:45

Answer 3

A:

Thanks both for your responses. Unfortunately your code wasn't quite what I needed (most likely due to the complex nature of what I'm after and my inability to explain my requirements) - but thanks to your example code, I've got a deeper understanding of XSL-T and created the following:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;
 <xsl:output method="html" />

 <xsl:template match="/">
    <div class="SideMenu">
      <!-- Loop through all L1 nodes -->
      <xsl:for-each select="Root/root/node">
        <xsl:if test="@enabled='1'" >
          <xsl:if test="@breadcrumb='1'" >
            <!-- Find active root node-->
            <!-- L0 nodes: Don't ever show (These are the horizontal tabs) -->

            <!-- Always show all children: L1 nodes -->
            <xsl:apply-templates select="child::node()[@url]" mode="BaseNode" ></xsl:apply-templates>

          </xsl:if>
        </xsl:if>
      </xsl:for-each>
    </div>
 </xsl:template>

  <!-- Template: Base node -->
  <xsl:template match="node" mode="BaseNode" >

    <xsl:choose>
      <xsl:when test="@breadcrumb='0'" >
        <!-- Non-breadcrumb L1 node -->
        <xsl:apply-templates select="." mode="NonShadedNode" ></xsl:apply-templates>

      </xsl:when>
      <xsl:when test="@breadcrumb='1'" >
        <!-- Child which is part of hierarchy -->
        <xsl:apply-templates select="." mode="ShadedNode" ></xsl:apply-templates>

        <!-- Drill down through hierarchy of active nodes-->
        <xsl:for-each select="descendant::node()[@url]">
          <xsl:if test="@breadcrumb='1'" >

            <!-- Is this the last node? If so, show children -->
            <xsl:choose>
              <xsl:when test="child::node()[@url]">
                  <!-- Not last node -->
                <xsl:apply-templates select="." mode="ShadedNode" ></xsl:apply-templates>

              </xsl:when>
              <xsl:otherwise>
                <!-- Last node: loop through all siblings -->

                <!-- THIS LOOP DOESN'T WORK CORRECTLY -->
                <xsl:for-each select="preceding-sibling::node()" >
                  <xsl:apply-templates select="." mode="ShadedNode" ></xsl:apply-templates>
                </xsl:for-each>

                <xsl:apply-templates select="." mode="SelectedNode" ></xsl:apply-templates>

                <xsl:for-each select="following-sibling::node()" >
                  <xsl:apply-templates select="." mode="ShadedNode" ></xsl:apply-templates>
                </xsl:for-each>

              </xsl:otherwise>
            </xsl:choose>

          </xsl:if>
        </xsl:for-each>

      </xsl:when>
    </xsl:choose>

  </xsl:template>

  <!-- Template: Non-shaded node -->
  <xsl:template match="node" mode="NonShadedNode" >
    <a>
      <xsl:attribute name="href">
        <xsl:value-of select="@url"/>
      </xsl:attribute>
      <xsl:attribute name="style">
        padding-left:<xsl:value-of select="@depth * 10"/>
      </xsl:attribute>
      <xsl:value-of select="@text"/>
    </a>
  </xsl:template>

  <!-- Template: Shaded node -->
  <xsl:template match="node" mode="ShadedNode" >
    <a class="SideMenu_Shaded">
      <xsl:attribute name="href">
        <xsl:value-of select="@url"/>
      </xsl:attribute>
      <xsl:attribute name="style">
        padding-left:<xsl:value-of select="@depth * 10"/>
      </xsl:attribute>
      <xsl:value-of select="@text"/>
    </a>
  </xsl:template>

  <!-- Template: Selected node -->
  <xsl:template match="node" mode="SelectedNode" >
    <a class="SideMenu_Selected">
      <xsl:attribute name="style">
        padding-left:<xsl:value-of select="@depth * 10"/>
      </xsl:attribute>
      <xsl:value-of select="@text"/>
    </a>
  </xsl:template>

</xsl:stylesheet>

This does exactly what I need, apart from the THIS DOESN'T WORK CORRECTLY section which for some reason also shows nodes which apart siblings... I'm currently looking at this and hoping it's a slight bug in my code.

Although if you can spot the problem, please let me know! :)

Here's the rendered HTML from the XSL-T:

<div class="SideMenu"><a href="/Home/Tester.aspx" style="&#xA;        padding-left:10">Tester </a><a class="SideMenu_Shaded" href="/Home/ChiefConstablesArea.aspx" style="&#xA;        padding-left:10">Chief Constables Area</a>
    Chief Constables Area
    Chief Constables Area
    <a class="SideMenu_Shaded" href="/Home/ChiefConstablesArea/ChiefsFocusGroups.aspx" style="&#xA;        padding-left:20">Chief's Focus Groups</a>
    <a class="SideMenu_Shaded" href="/Home/ChiefConstablesArea/AbouttheChief.aspx" style="&#xA;        padding-left:20">About the Chief</a>
    <a class="SideMenu_Shaded" href="/Home/ChiefConstablesArea/ChiefsOfficerGroup.aspx" style="&#xA;        padding-left:20">Chief's Officer Group</a>
    <a class="SideMenu_Selected" style="&#xA;        padding-left:20">Chief's Messages</a>
    <a class="SideMenu_Shaded" href="/Home/ChiefConstablesArea/ForceAwardsScheme.aspx" style="&#xA;        padding-left:20">Force Awards Scheme</a>
  <a href="/Home/ActiveForumLitetrial.aspx" style="&#xA;        padding-left:10">Active Forum Lite trial</a></div>

Peter Bridger 2009-12-21 15:43:41

<xsl:for-each select="preceding-sibling::node()" >needed to be<xsl:for-each select="preceding-sibling::node()[@url]" >

Peter Bridger 2009-12-22 09:40:05

ansaurus

tags:

views:

answers:

DotNetNuke + XPath = Custom navigation menu

related questions