ansaurus

Question

How do I convert CSV into an HTML table using Perl?

Answer 1

+5 A:

Allow me to demonstrate with a smaller example.

my $f;
while ($line = <F>) {
    $f = $line;
}
print $f;

The above code will read every line of the file F, assigning each line to the variable $f. Each time it assigns a new line, the previous line is overwritten. When it reaches the end of the file, it prints out the value of $f once.

my $f;
while ($line = <F>) {
    $f = $line;
    print $f;
}

The above code has the print inside the loop, so the print will run for each line of the input. You will want to make a similar modification to your code to get the output you expect.

Greg Hewgill 2008-10-14 06:28:50

Answer 2

+12 A:

You need to output the table rows inside the while loop, as that's where you are reading the lines.

So change the code so that it

outputs table headers
reads the file line by line outputting table rows
outputs table footer

Here's how your loop might look if a little simplified...

while ($line=<F>)
{  
    print "<tr>";
    my @cells= split ',',$line;
    foreach my $cell (@cells)
    {
       print "<td>$cell</td>";
    }
    print "</tr>";
}

Paul Dixon 2008-10-14 06:30:25

it works buddy...thanks..:-)

2008-10-14 06:56:29

Answer 3

+3 A:

The reason you were only seeing the last line was that you ran the print's after reading the entire file and discarding each line when the next was read.

To be honest, there's various things wrong with that code. I'll mention a couple and address those in the code snippet below.

Don't parse CSV data yourself (the split). Use Text::CSV or -- if you need better performance -- Text::CSV_XS.
Your HTML is invalid. You don't close all tags and in particular, title should be in head, but not body.
You should use a templating module for inserting tabular data into a web page. Examples: HTML::Template or Template Toolkit.
At the very least, use functions to abstract out the redunant code.
Better yet, use the fact that the formatting of the data is also data. That's why it should be treated as such.
If you every find you're declaring lots of variables with numbers attached ($f1,$f2...), you really want an array: @fields = split /,/, $line;

use strict;
use warnings;
use CGI qw();
use Text::CSV;

my $cgi = CGI->new();
print $cgi->header();

my $file ='MyFile.txt';

# should really use a templating module from CPAN,
# but let's take it step by step.
# Any of the following would fit nicely:
# - Template.pm (Template Toolkit)
# - HTML::Template, etc.
my $startHtml = <<'HERE';
<html>
<head> <title>FUSION SHIFT REPORT</title> </head>
<body bgcolor="#4682B4">
<div align="left">
<table cellpadding="1" cellspacing="1" border="1" bordercolor="black" width="100%">
HERE
my $endHtml = <<'HERE';

</table>

</body>
<html>
HERE

my @columns = (
  { name => 'RECORD No.', width => 12 },
  { name => 'TESTER No.', width => 12 },
  { name => 'DATE', width => 12 },
  { name => 'TIME', width => 13 },
  { name => 'DEVICE NAME', width => 11 },
  { name => 'TEST PROGRAM' },
  { name => 'DEVICE FAMILY' },
  { name => 'SMSLOT', width => 13 },
  { name => 'DIE LOT', width => 13 },
  { name => 'LOADBOARD', width => 12 },
  { name => 'TESTER', width => 12 },
  { name => 'SERIAL NUMBER', width => 12 },
  { name => 'TESTER CONFIG', width => 13 },
  { name => 'SMSLOT', width => 11 },
  { name => 'PACKAGE' },
  { name => 'SOCKET' },
  { name => 'ROOT CAUSE 1', width => 13 },
  { name => 'ROOT CAUSE 2', width => 13 },
  { name => 'ROOT CAUSE 3', width => 13 },
);


my $csv = Text::CSV->new();
open my $fh, '<', $file
  or die "Could not open file '$file': $!"; # should generate a HTML error here

# print header
print $startHtml;
print_table_header(\@columns);

while (defined(my $line = <$fh>)) {
  $csv->parse($line);
  # watch out: This may be "tainted" data!
  my @fields = $csv->fields();
  @fields = @fields[0..$#columns] if @fields > @columns;
  print_table_line(\@fields);
}

close $fh;

print $endHtml;




sub print_table_header {
  my $columns = shift;
  print "<tr>\n";
  foreach my $column (@$columns) {
    my $widthStr = (defined($column->{width}) ? ' width="'.$column->{width}.'"' : '');
    my $colName = $column->{name};
    print qq{<td$widthStr bgcolor="#00FF00"><font size="2">$colName</font></td>\n};
  }
  print "</tr>\n";
}

sub print_table_line {
  my $fields = shift;
  print "<tr>\n";
  foreach my $field (@$fields) {
    print qq{<td bgcolor=\"#ADD8E6\"><font size="2">$field</font></td>\n};
  }
  print "</tr>\n";
}

tsee 2008-10-14 15:54:51

Answer 4

+6 A:

wfsp 2008-10-14 15:58:48

Answer 5

A:

Please close your <font> tags. Just because the browser will handle their lack doesn't mean they're not valuable to include.

Andy Lester 2008-10-14 22:39:57

Answer 6

+4 A:

$f1,$f2,$f3,$f4

Any time you see code like that alarm bells should go off. Use an array.

AmbroseChapel 2008-10-15 01:39:48

Thank you. You saved me from having to point that out.

Ovid 2008-10-15 12:30:31

ansaurus

tags:

views:

answers:

How do I convert CSV into an HTML table using Perl?

related questions