split function extension

Question

Hi, I am learning the sample code from split function.

Sample code.

#!C:\Perl\bin\perl.exe
use strict;
use warnings;

my $info = "Caine:Michael:Actor:14, Leafy Drive";
my @personal = split(/:/, $info);
# @personal = ("Caine", "Michael", "Actor", "14, Leafy Drive");

If change the $info = "Caine Michael Actor /* info data */"; How to use the split(/ /, $info) to export the result below.

# @personal = ("Caine", "Michael", "Actor", "info data");

Thank you.

Answer 1

Cooked something up :). Does work only for you example. Cannot generalize

use strict;
use warnings;

my $info = "Caine Michael Actor /* info data */";
if($info=~m{/\*\s*(.*?)\s*\*/})
{
    my $temp = $1;
    $temp=~s{\s+}{##}g;
    $info=~s{/\*\s*(.*?)\s*\*/}{$temp};
}
my @personal = split(/ /, $info);
foreach(@personal)
{
    s{##}{ }g;
    print "$_\n";
}

Output:

C:>perl a.pl
Caine
Michael
Actor
info data

Answer 2

It really is better to use regex for this:

$info = "Caine Michael Actor /* info data */";
$info =~ /(\w+)\s+(\w+)\s+(\w+).*\/\*(.+)\*\//;
@personal = ($1, $2, $3, $4);

Mainly because your input string has ambiguities related to word separators not easily handled by split.

In case you're wondering how to read the regex:

/
    (\w+)   # CAPTURE a sequence of one of more word characters into $1
    \s+     # MATCH one or more white space
    (\w+)   # CAPTURE a sequence of one of more word characters into $2
    \s+     # MATCH one or more white space
    (\w+)   # CAPTURE a sequence of one of more word characters into $3
    .*      # MATCH zero or more of anything
    \/\*    # MATCH the opening of C-like comment /*
    (.+)    # CAPTURE a sequence of one or more of anything into $4
    \*\/    # MATCH the closing of C-like comment */
/x

Answer 3

Alternative approach:

Have you considered using the 3-parameter version of split:

$info = "Caine Michael Actor /* info data */";
@personal= split(' ',$info,4);

resulting in

@personal=('Caine','Michael','Actor','/* info data */');

then you would have to remove / * * / .. to get your result...

Answer 4

since there isn't an answer yet that handles the general case, here goes:

split isn't your best bet here, and since the delimiter can be both a matched and non matched character, it will be clearest to invert the problem and describe what you do what to match, which in this case is either a string of non space characters, or the contents of a c style comment.

use strict;
use warnings;

my $info = "Caine Michael Actor /* info data */";
my @personal = grep {defined} $info =~ m! /\* \s* (.+?) \s* \*/ | (\S+) !xg;

say join ', ' => @personal;

that will return a list of words / contents of comments in any sequence you need. The syntax highlighter doesn't highlight the above regex properly, the regex is everything between !