How can I extract A records that also have TXT records in Perl?

Question

Hi, I'm having data like this:

uniqname1.foo.bar IN A 10.0.0.1  
uniqname1.foo.bar IN TXT "abcdefg"  
uniqname2.foo.bar IN A 10.0.0.2  
uniqname2.foo.bar IN TXT "xyz"  
uniqname3.foo.bar IN A 10.0.0.3  
uniqname4.foo.bar IN A 10.0.0.4`

You get the picture, not every host has a TXT, some do. I try to get a regex which would print out 3 values for hosts that have a TXT, in that case the output would be:

uniqname1.foo.bar 10.0.0.1 abcdefg  
uniqname2.foo.bar 10.0.0.2 xyz`

Answer 1

I wouldn't use a regular expression for this. You're likely going to run into some files that have things in a different order, completely screwing up your pattern. Instead, create a data structure to hold the records, select the ones with TXT entries, and from the TXT entries look up the A data. Although regular expressions are fun and powerful, hashes are sometimes even more powerful:

use 5.010;

while( <DATA> ) {
    chomp;
    # maybe another normalization step here
    my( $name, undef, $type, $data ) = split;

    $records{$type}{$name} = $data;
    }

foreach my $txt_record ( keys %{ $records{'TXT'} } ) {
    my $txt_data = $records{'TXT'}{$txt_record};
    my $a_data   = $records{'A'}{$txt_record};

    say join ' ', $txt_record, $a_data, $txt_data;
    }

__DATA__
uniqname1.foo.bar IN A 10.0.0.1
uniqname1.foo.bar IN TXT "abcdefg"
uniqname2.foo.bar IN A 10.0.0.2
uniqname2.foo.bar IN TXT "xyz"
uniqname3.foo.bar IN A 10.0.0.3
uniqname4.foo.bar IN A 10.0.0.4

Answer 2

In perl:

while ($s =~ m/^([\w.]+) IN A ([\d.]+)(?:\r|\r\n|\n)$1 IN TXT "([\w+])"/m) {
    print "$1 $2 $3\n";
}

Where $s is your data blob you have above.

I haven't tested it, but the above is close.

Answer 3

Do you really need to parse the textual zone data? Why not query for that data programmatically with Net::DNS?

For example:

use Net::DNS;
my $res = Net::DNS::Resolver->new;
my $txtquery = $res->query("example.com", "TXT");
my $aquery = $res->query("example.com", "A");

if ($txtquery and $aquery) {
    ($txtquery->answer)[0]->print;
} else {
    print "query failed: ", $res->errorstring, "\n";
}

Answer 4

another way

#!/usr/bin/perl
while (<>) {
    @F = split ' ', $_ ;
    if ($F[2] eq 'A') {
        $a{$F[0]} = $a{$F[0]} . ' ' . $F[$#F];
    }
    if ($F[2] eq 'TXT') {
        print "$F[0] $a{$F[0]} $F[$#F] \n";
    }
}

output

$ perl test.pl file
uniqname1.foo.bar  10.0.0.1 "abcdefg"
uniqname2.foo.bar  10.0.0.2 "xyz"