How can I search and replace a match a specific number of times in a string in Perl?

Question

How can I search and replace a match with specific number of times using s///;. For example:

$string="abcabdaaa";

I want to replace a with i in $string n times. How can I do that? n is an integer provided by user.

Answer 1

I'm not aware of any flag that would do that. I'd simply use a loop:

for (my $i = 0; $i < $n; $i++)
{
   $string =~ s/a/i/;
}

Answer 2

Just substitute $n times:

$string =~ s/a/i/ for 1..$n;

This will do it.
More general solution would be global substitution with counter:

my $i = 0; # count the substitutions made
$string =~ s/(a)/ ++$i > $n ? $1 : "i" /ge; 

Answer 3

you can try this:

$str1=join('i',split(/a/,$str,$n));

Answer 4

The simple answer probably doesn't do want you want.

my $str = 'aaaa';
$str =~ s/a/a_/ for 1..2;
print $str, "\n"; # a__aaa. But you want a_a_aa, right?

You need to count the replacements yourself, and act accordingly:

$str = 'aaaa';
my $n = 0;
$str =~ s/(a)/ ++$n > 2 ? $1 : 'a_' /ge;
print $str, "\n";

See the FAQ, How do I change the Nth occurrence of something? for related examples.

Answer 5

Using

sub substitute_n {
  my $n = shift;
  my $pattern = shift;
  my $replace = shift;
  local $_ = shift;

  my $i = 1;
  s{($pattern)} {
    $i++ <= $n ? eval qq{"$replace"} : $1;
  }ge;

  $_;
}

You can then write

my $s = "***ab***c";

print "[", substitute_n(2, qr/\*/, '$1\n', $s), "]\n";

to get the following output:

[*
*
*ab***c]

Answer 6

Here is a way to do based on the comment you made to eugene y's answer

#!/usr/bin/perl

use strict; use warnings;

my $string = '***ab***c';
my $n = 3;

1 while $n -- and $string =~ s/\*([^\n])/*\n$1/;

print "$string\n";

Output:

*
*
*
ab***c