What is the best way in Perl to copy files into a yet-to-be-created directory tree?

Question

What is the best way in Perl to copy files to a yet to be created destination directory tree?

Something like

copy("test.txt","tardir/dest1/dest2/text.txt");

wont work since the directory tardir/dest1/dest2 does not yet exist.

What is the best way to copy with directory creation in Perl?

Answer 1

use File::Basename qw/dirname/;
use File::Copy;

sub mkdir_recursive {
    my $path = shift;
    mkdir_recursive(dirname($path)) if not -d dirname($path);
    mkdir $path or die "Could not make dir $path: $!" if not -d $path;
    return;
}

sub mkdir_and_copy {
    my ($from, $to) = @_;
    mkdir_recursive(dirname($to));
    copy($from, $to) or die "Couldn't copy: $!";
    return;
}

Answer 2

use File::Path;
use File::Copy;

my $path = "tardir/dest1/dest2/";
my $file = "test.txt";

if (! -d $path)
{
  mkpath($path) or die "Failed to create $path: $!\n";
}

copy($file,$path) or die "Failed to copy $file: $!\n";

Answer 3

File::Copy::Recursive::fcopy() is non-core but combines the File::Path::mkpath() and File::Copy::copy() solution into something even shorter, and preserves permissions unlike File::Copy. It also contains other nifty utility functions.

Answer 4

See the other answers for doing the copying, but for creating the directory Path::Class is very nice to use:

use Path::Class;

my $destination_file  = file('tardir/dest1/dest2/test.txt');
$destination_file->dir->mkpath;

# ... do the copying here