inspect the parameters to "use", and pass on the rest?

Question

I have a Perl module and I'd like to be able to pick out the parameters that my my module's user passed in the "use" call. Whichever ones I don't recognize I'd like to pass on. I tried to do this by overriding the "import" method but I'm not having much luck.

EDIT:

To clarify, as it is, I can use my module like this:

use MyModule qw/foo bar/;

which will import the foo and bar methods of MyModule. But I want to be able to say:

use MyModule qw/foo doSpecialStuff bar/;

and look for doSpecialStuff to check if I need to do some special stuff at the beginning of the program, then pass qw/foo bar/ to the Exporter's import

Answer 1

The typical use of Exporter is to declare your module to inherit from Exporter, and to have Exporter's import method called implicitly when your module is used. But this keeps you from creating your own import method for your module.

The workaround is to use Exporter's export_to_level method, which performs Exporter's functions without explicitly going through the Exporter::import method. Here's a typical way to use it:

package My::Module;
use base 'Exporter';   # or use Exporter; our @ISA=qw(Exporter);
our @EXPORT = qw(...);
our @EXPORT_OK = qw(...);
our %EXPORT_TAGS = (...);

sub import {
    my ($class,@import_args) = @_;
    my @import_args_to_pass_on = ();
    foreach my $arg (@import_args) {
       if (... want to process this arg here ...) {
          ...
       } else {
          push @import_args_to_pass_on, $arg;
       }
    }
    My::Module->export_to_level(1, "My::Module", @import_args_to_pass_on, @EXPORT);
    #or:  $class->export_to_level(1, $class, @import_args_to_pass_on, @EXPORT);
}

Answer 2

I have done it this way in my modules:

sub import {
    return if not @_;
    require Exporter;
    my $pkg = shift;

    # process @_ however you want

    unshift @_, $pkg;
    goto &Exporter::import;
}

you can also inherit from Exporter if you want unimport and the like.