ansaurus

Question

xslt (table) by matching the attribute value.

Answer 1

+1 A:

Your stylesheet has only has a single template rule: match="sparql/results" which should be matched. Does your input document contain namespaces which are not shown in the example?

If your xml elements are in a namespace, even if it is the default namespace for the document, you must use namespace prefixes in any XPath expressions and template match rules. It is the namespace uri and not the prefix that matters. Note that attributes will not be in the default namespace, they only have a namespace if their name has a prefix.

<xsl:stylesheet version="1.0"
                xmlns:s="http://www.w3.org/2005/sparql-results#"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;

    <xsl:template match="s:results">

The built-in template rules generate the output that you were seeing, since they:

match all templates, and perform an apply-templates
copy text nodes to output

I have added a rule to match /, and then explicitly select the desired elements at each step.

This example produces a HTML table from your input, containing columns for first name and last name.

<xsl:stylesheet version="1.0"
    xmlns:s="http://www.w3.org/2005/sparql-results#"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;
    <xsl:output method="html" encoding="UTF-8"/>

    <xsl:template match="/">
        <html>
            <head><title>persons</title>
            </head>
            <body>
                <xsl:apply-templates select="s:sparql/s:results" />
            </body>
        </html>
    </xsl:template>


    <xsl:template match="s:results">
        <table>
            <thead>
                <tr>
                    <td>
                        <xsl:text>Link</xsl:text>
                    </td>
                    <td>
                        <xsl:text>First name</xsl:text>
                    </td>
                    <td>
                        <xsl:text>Last name</xsl:text>
                    </td>
                </tr>
            </thead>
            <tbody>
                <xsl:apply-templates />
            </tbody>
        </table>
    </xsl:template>

    <xsl:template match="s:result">
        <tr>
            <td>
                <a href="{s:binding[@name='s']/s:uri}">
                    <xsl:value-of select="s:binding[@name='s']/s:uri" />
                </a>
            </td>
            <td>
                <xsl:value-of select="s:binding[@name='fname']/s:literal" />
            </td>
            <td>
                <xsl:value-of select="s:binding[@name='lname']/s:literal" />
            </td>
        </tr>
    </xsl:template>

</xsl:stylesheet>

Lachlan Roche 2010-03-14 13:53:19

my output is like this ? http://tn.gov.in/Person/41 Gayathri Vasudevan http://tn.gov.in/Person/43 Vivek Vasudevan http://tn.gov.in/Person/37 Magesh Vasudevan http://tn.gov.in/Person/39 Vasudevan Srinivasan

Magesh 2010-03-14 14:25:29

not getting any table ?

Magesh 2010-03-14 14:26:02

@Magesh please edit the question and add an example of the output you want

Lachlan Roche 2010-03-14 14:43:42

i tried again with yours but my output is same...!!!not able to figure out my mistake..!

Magesh 2010-03-14 16:25:10

finally it worked...! thanks alot lachlan..!

Magesh 2010-03-16 07:33:27

Answer 2

A:

Hi,

I didn't try Lachlan's answer, but it looks good to me. I put this together quickly that gives the output you asked for (it's not too different, and I haven't done any formatting).

<xsl:output method="html"/>

<xsl:template match="/">
    <html>
        <head></head>
        <body>
            <xsl:apply-templates></xsl:apply-templates>
        </body>
    </html>
</xsl:template>

<xsl:template match="results">
    <table>
        <tr>
            <th>Fname</th>
            <th>Lname</th>
        </tr>
        <xsl:for-each select="result">
            <tr>
                <td><xsl:value-of select="binding[@name='fname']"/></td>
                <td><xsl:value-of select="binding[@name='lname']"/></td>
            </tr>
        </xsl:for-each>    
    </table>
</xsl:template>

Mark Cooper 2010-03-14 17:20:36

my result is same !!!!!!!!!!!!!!!! getting struck with this for past 2 days.. not able to procedd !!!http://tn.gov.in/Person/41 Gayathri Vasudevan http://tn.gov.in/Person/43 Vivek Vasudevan http://tn.gov.in/Person/37 Magesh Vasudevan http://tn.gov.in/Person/39 Vasudevan Srinivasan

Magesh 2010-03-14 18:33:40

ansaurus

tags:

views:

answers:

xslt (table) by matching the attribute value.

related questions