How do I select child nodes that don't have a specific parent as an ancestor?

Question

We use CruiseControl for our build server. It compiles our applications using MSBuild and uses its own XML logger that spits out something like the following XML:

<project name="CI">
  <target name="CompileApp">
    <project name="Project1.csproj">
      <target name="build">
        <error>Compilation error one!</error>
      </target>
      <target name="BeforeBuild">
        <project name="Project2.csproj">
          <target name="build">
            <error>Compilation error two!</error>
          </target>
        </project>
      </target>
    </project>
  </target>
</project>

I want to transform this into a report that outputs each project's errors. I don't want to report on the errors in other projects.

  Project "Project1.csproj": 1 error(s)
  Error(s):  
  Compilation error one!

  Project "Project2.csproj": 1 error(s)
  Error(s):
  Compilation error two!

This is the closest I've gotten, but it's not right. It doesn't filter out project2's errors when showing project1's errors.

<xsl:template>
  <xsl:variable select="//project[.//error]" name="projects.with.errors" />
  <xsl:apply-templates select="$projects.with.errors" />
</xsl:template>

<xsl:template match="project">
   <xsl:variable select="./*[not(project)]//error" name="errors" />
   <xsl:if test="count($errors) > 1">
      <!-- display errors -->
   </xsl:if>
</xsl:template>

How can I filter out any error nodes that have a different project ancestor than my current project node? I.e., how can I only select descendant error nodes that don't have a project ancestor?

The error nodes can have an arbitrary number of parent elements (usually , but not always).

Answer 1

This transformation:

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;
 <xsl:output method="text"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kProjectByName" match="project"
  use="@name"/>

 <xsl:key name="kErrByProject" match="error"
  use="ancestor::project[1]/@name"/>

 <xsl:template match="/">
   <xsl:for-each select=
    "//project
          [generate-id()
          =
           generate-id(key('kProjectByName', @name)[1])
           ]
    ">
     <xsl:variable name="vErrors" select=
       "key('kErrByProject', @name)"/>

     <xsl:if test="$vErrors">
         Project <xsl:value-of select="@name"/><xsl:text>: </xsl:text>
         <xsl:value-of select="count($vErrors)"/> errors.
         Errors:
         <xsl:for-each select="$vErrors">
           <xsl:value-of select="."/>
         </xsl:for-each>
         <xsl:text>&#xA;</xsl:text>
     </xsl:if>
   </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

when applied on the provided XML document:

<project name="CI">
  <target name="CompileApp">
    <project name="Project1.csproj">
      <target name="build">
        <error>Compilation error one!</error>
      </target>
      <target name="BeforeBuild">
        <project name="Project2.csproj">
          <target name="build">
            <error>Compilation error two!</error>
          </target>
        </project>
      </target>
    </project>
  </target>
</project>

produces the wanted, correct result:

 Project Project1.csproj: 1 errors.
 Errors:
 Compilation error one!

 Project Project2.csproj: 1 errors.
 Errors:
 Compilation error two!

Answer 2

Here's a quite simple solution:

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;
  <xsl:output method="text" />

  <xsl:template match="/">
    <xsl:apply-templates select="//project[.//error]" />
  </xsl:template>

  <xsl:template match="project">
    <xsl:variable name="errors" select=".//error[ancestor::project[1]/@name = current()/@name]" />
    <xsl:if test="count($errors) != 0">
      <xsl:value-of select="concat('Project &quot;',@name,'&quot;: ',count($errors),' error(s)&#10;Error(s):&#10;')" />
      <xsl:apply-templates select="$errors" />
      <xsl:text>&#10;</xsl:text>
    </xsl:if>
  </xsl:template>

  <xsl:template match="error">
    <xsl:value-of select="concat(.,'&#10;')" />
  </xsl:template>
</xsl:stylesheet>

This stylesheet basically just calls a template for each project element anywhere in the document tree. This template stores a list of all errors in a variable, using an xpath that selects all error elements that are a descendant of the current project and have the current project element as it's first project ancestor. Then, if there are any, it just outputs the appropriate header text and applies a template to each error.

I'm using 
 for the new line character here, but if you prefer the windows newline, you can use 
.

Minor caveat to this one; you'll end up with a blank line at the bottom of your output, as it adds one at the bottom of every project to separate it from the next.

Answer 3

We are so used to complex requirements, we are puzzled when it appears a more simple, I think.

So, with:

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"&gt;
  <xsl:output method="text" />

  <xsl:template match="project[../..]">
      <xsl:value-of select="concat('&#xA;',
            'Project &quot;',@name,'&quot;: ',count(target/error),' error(s)&#xA;',
              'Error(s):&#xA;')" />
      <xsl:apply-templates/>
  </xsl:template>

  <xsl:template match="error">
    <xsl:value-of select="concat(.,'&#xA;')" />
  </xsl:template>
</xsl:stylesheet>

You get:

Project "Project1.csproj": 1 error(s)
Error(s):
Compilation error one!

Project "Project2.csproj": 1 error(s)
Error(s):
Compilation error two!