File name length limit for AppleScript in URL Access Scripting?

Question

I'm having a strange AppleScript issue, and can't seem to figure out the underlying cause, or a solution. I'm trying to download files with a process that mimics the one below. This code fails for me, reporting "URL Access Scripting got an error: Can’t make some data into the expected type." number -1700 to item"

If I remove 3 characters from the local path name (and it doesn't seem to matter which 3), then it runs fine. If I only remove 2 characters, it doesn't throw an error, but the file it downloads is a corrupted JPG. I tried doing the same with curl in a "do shell script" line, and it seemed to fail too for any file name length, albeit silently (returning ""). What's causing this, and what can I do about it?

tell application "URL Access Scripting"
    download "http://interfacelift.com/wallpaper_beta/grab/02331_veiledinclouds_2560x1600.jpg" to "/Users/abc/Downloads/02331_veiledinclouds_2560x1600.jpg"
end tell

Answer 1

Your biggest problem is you're using a posix-style path (using slashes) when you should be using a mac-style path (with colons). Applescript uses colon delimited paths. We can convert between the two using "posix path" to go from colons to slashes and "posix file" to go from slashes to colons.

And you can't just pass the path as a string. In applescript we use file specifiers... which is why I put the word file in front of the string path. So this works once we fix that.

set posixPath to "/Users/abc/Downloads/02331_veiledinclouds_2560x1600.jpg"
set macPath to (POSIX file posixPath) as text

tell application "URL Access Scripting"
    download "http://interfacelift.com/wallpaper_beta/grab/02331_veiledinclouds_2560x1600.jpg" to file macPath
end tell

However, there must be a filename length issue because when I run it the filename of the downloaded file is shortened to 31 characters.

EDIT: Here's a script to truncate, download, and rename the file if necessary.

set posixPath to "/Users/abc/Downloads/02331_veiledinclouds_2560x1600.jpg"
set baseName to do shell script "/usr/bin/basename " & quoted form of posixPath

set needsRenaming to false
if (count of baseName) is greater than 31 then
    set downloadName to text -31 thru -1 of baseName
    set basePath to do shell script "/usr/bin/dirname " & quoted form of posixPath
    set posixPath to basePath & "/" & downloadName
    set needsRenaming to true
end if

set macPath to (POSIX file posixPath) as text

tell application "URL Access Scripting"
    download "http://interfacelift.com/wallpaper_beta/grab/02331_veiledinclouds_2560x1600.jpg" to file macPath
end tell

if needsRenaming then
    tell application "Finder"
        set name of file macPath to baseName
    end tell
end if

Answer 2

I'm willing to bet that this function still calls some ancient Carbon (or pre-Carbon) API call that only allows 31 characters. Some of the Google links related to this go back to 2003, and as far as Mac OS is concerned, both the year and the specific 31 character limit point to this being an outdated API that was never brought up to date. This is the problem with the darker corners of Applescript. Maybe Satimage or someone has made a Scripting Addition that works around this. I think you are stuck and need to get help from somewhere outside of this addition. I would love to proven wrong on this one because I couldn't get it to work no matter what I tried.

Answer 3

I ultimately decided to download to a temporary, shorter name and then rename it with Finder. The rewritten script is below:

tell application "URL Access Scripting"
    set tempFileName to "abc.jpg"
    set downloadPath to (POSIX path of (path to downloads folder))

    set tempFile to download "http://interfacelift.com/wallpaper_beta/grab/02331_veiledinclouds_2560x1600.jpg" to downloadPath & tempFileName
end tell

tell application "Finder" to set name of file tempFile to "02331_veiledinclouds_2560x1600.jpg"

I prefer the simplicity of this approach to regulus6633's approach, which only renames the file if it needs it.