perplexing garbage collection issue

Question

1) var x1:X = new X();
2) var x2:X = new X();
...
3) x1.z = new SWFLoader(...);
...
4) x2.z = x1.z;
5) x1.z = null
6) x1 = null;

The last statement is useless because statement 4 guarantees that x1 and anything else it contains will never ever be garbage collected as long as x2.z exists. Does anyone else think this is bizarre? This was a major shock and drawback to me for something that I needed to do. Is there any workaround at all?

The only reason this would make sense is if everything in x1 was stored in contiguous memory or something, but when you say "x1.z = new ..." in most languages that implies its going and allocating a new block of memory somewhere else and returning a pointer to it (a pointer that is subsequently assigned to x2.z as well.) I was always interpreting "reference" in actionscript as "pointer".

Of course some might say, well you could still delete everything in x1 individually. But if not for statement 4 above, statement 6 would mark everything in x1 for deletion.

(Note: the only reason I put statement 5 in was to tell flash player "I really don't care about x1.z anymore", but it made no difference.)

Answer 1

If I understood your question correctly, you are saying that the following code should leak x1. But it doesn't. How are you testing that x1 is not eligible for collection? Can you post some working code that reproduces the problem?

package {
    import flash.display.MovieClip;
    import flash.display.Sprite;
    import flash.net.URLLoader;
    import flash.system.System;
    import flash.utils.Dictionary;
    import flash.utils.setInterval;

    public class test extends Sprite
    {

        private var _dict:Dictionary = new Dictionary(true);

        private var x1:Foo;
        private var x2:Foo;

        public function test()
        {
            testGC();
            setInterval(function():void { 
                traceCount();
            },100);         
        }

        private function testGC():void {
            x1 = new Foo();
            x2 = new Foo();

            _dict[x1] = true;
            _dict[x2] = true;

            x1.z = new URLLoader();
            x2.z = x1.z;

            x1 = null;


        }

        private function traceCount():void {
            var count:int = 0;
            for each(var i:* in _dict) {
                count++;
            }
            trace(count);
            System.gc();
        }

    }
}

import flash.net.URLLoader;

class Foo {

    public var z:URLLoader;
}

Answer 2

I just tried to duplicate this with new code and was unable to, so I'm at a loss. The original code is reverted now and the class was much larger than the test scenario I just came up with. Guess I better close this. Here is the test scenario I just ran, FWIW:

package my_components 
{

  import mx.controls.SWFLoader;

  public class Test {

    public var arr:Array = new Array();

    public var z:SWFLoader;

    public function Test() {
      for (var n:int=0; n<1000000; n++)
        arr.push(n);
    }  

  }

}       

---

private var x1:Test;
private var x2:Test;

private function InitWR(fnCFG:String = null):void {

  try { 
    new LocalConnection().connect('foo'); 
    new LocalConnection().connect('foo'); 
  } catch (e:*) {} 

  Dumper.info(System.totalMemory.toString());   

  x1 = new Test();
  x1.z = new SWFLoader();

  x2 = new Test();

  x2.z = x1.z;

  x1 = null;

  try { 
    new LocalConnection().connect('foo'); 
    new LocalConnection().connect('foo'); 
  } catch (e:*) {} 

  Dumper.info(System.totalMemory.toString());   

  Dumper.info("---------------");