How do I remove all hyphens with a Perl regex?

Question

I thought this would have done it...

$rowfetch = $DBS->{Row}->GetCharValue("meetdays");
$rowfetch = /[-]/gi;
printline($rowfetch);

But it seems that I'm missing a small yet critical piece of the regex syntax.

$rowfetch is always something along the lines of:

------S
-M-W---
--T-TF-

etc... to represent the days of the week a meeting happens

Answer 1

$rowfetch =~ s/-//gi

That's what you need for your second line there. You're just finding stuff, not actually changing it without the "s" prefix.

You also need to use the regex operator "=~" for this.

Answer 2

Here is what your code presently does:

# Assign 'rowfetch' to the value fetched from:
#      The function 'GetCharValue' which is a method of: 
#         An Value in A Hash Identified by the key "Row" in:
#          Either a Hash-Ref or a Blessed Hash-Ref
#      Where 'GetCharValue' is given the parameter "meetdays"
$rowfetch = $DBS->{Row}->GetCharValue("meetdays");
# Assign $rowfetch to the number of times 
#  the default variable ( $_ ) matched the expression /[-]/ 
$rowfetch = /[-]/gi;
#  Print the number of times. 
printline($rowfetch);

Which is equivalent to having written the following code:

$rowfetch = ( $_ =~ /[-]/ ) 
printline( $rowfetch );

The magic you are looking for is the

=~

Token instead of

=

The former is a Regex operator, and the latter is an assignment operator.

There are many different regex operators too:

if( $subject =~ m/expression/  ){
}

Will make the given codeblock execute only if $subject matches the given expression, and

$subject =~ s/foo/bar/gi

Replaces ( s/) all instances of "foo" with "bar", case-insentitively (/i), and repeating the replacement more than once(/g), on the variable $subject.

Answer 3

Using the tr operator is faster than using a s/// regex substitution.

$rowfetch =~ tr/-//d;

Benchmark:

use Benchmark qw(cmpthese);

my $s = 'foo-bar-baz-blee-goo-glab-blech';

cmpthese(-5, {
  trd => sub { (my $a = $s) =~ tr/-//d },
  sub => sub { (my $a = $s) =~ s/-//g },
});

Results on my system:

         Rate  sub  trd
sub  300754/s   -- -79%
trd 1429005/s 375%   --

Answer 4

Off-topic, but without the hyphens, how will you know whether a "T" is Tuesday or Thursday?