Concise foreach expression in one line

Question

In Perl, one can often avoid using control blocks, like this:

print "$_\n" foreach(@files);

instead of:

foreach(@files){
  print "$_\n";
}

How does this syntax work in the following, more complex case:

die("Not a file: $_") unless -f $_ foreach(@files);

It gives me a syntax error. I'm not trying to write obfuscated code, it's just an unimportant part in the program, and so I want to express it as concisely as possible.

SUMMARIZED ANSWERS:

I can accept only one answer as the accepted answer, but I like the following ones from Chris and Jon best.

This one uses foreach as I intended, but without the syntax error:

-f or die "Not a file: $_" foreach @files;

And the following one is at least as good. I like that die is at the beginning of the statement because that's what the reader's attention should be directed toward:

die("Not a file: $_") for grep {!-f} @files;

Answer 1

Well, you may not be intending to write obfuscated code, but I'd say that you're certainly trying to.

Would two lines (or even a block on one line, like Brent.Longborough suggests) instead of one be so bad? Honestly, this is the reason I generally hate trying to debug/edit other peoples' perl code, a large number of people that write in perl seem to be obsessed with doing almost everything in the most "clever" way possible, instead of doing it in a way that's easy to understand for someone else reading.

Answer 2

If you are not trying to write obfuscated code, then you should not try to write it like this. You are taking something that should be simple and making it hard to understand.

Answer 3

You could either use @Brent.Longborough's answer, or if you really want postfix, do:

do { die("Not a file: $_") unless -f $_ } foreach(@files);

However, I agree with the others, just because this is "an unimportant part" doesn't mean that concise is better. Readability counts.

Answer 4

If the error test is the primary point of this code, it might make sense for it to have the prime location at the beginning of the line. A slight improvement would be to use grep:

die("Not a file: $_") for grep {!-f} @files;

But if you plan on looping through the files for some other reason in that part of the code, it would be better to add it to the body of the loop.

Answer 5

Damn, Jon just beat me to grep.

But I have a larger question: how is it not important if you're actually going to bail out if you find some non-files in your array? (As opposed to, say, removing those items, warning the user and then processing the rest of the list.) I would think that killing the whole shebang is a reasonably important part of the program.

In any case, you can't do exactly what you want with postfix modifiers since you can only have one thing on either side of them. So you can't have both the unless and the foreach. From the top of the relevant bit of perldoc perlsyn:

Any simple statement may optionally be followed by a SINGLE modifier, just before the terminating semicolon (or block ending).

Answer 6

Just to be Perlish (TMTOWTDI) you can use logic short-circuiting:

-f or die "Not a file: $_" foreach @files;

Tested on OS X and works.

As a side note, -f or die looks like a lot of common open() or die constructs I see in Perl, and still (I think) shows the intention of the line (to die under certain conditions).

Answer 7

You're thinking too hard. Here it is on one line with no acrobatics:

 foreach ( @files ) { die( "Not a file!" ) unless -f }

You might play around with the stuff inside the block to golf it down, but removing the parens and the braces isn't helping you any, and is probably going to confuse the next programmer who has to look at it.

You probably have something more complicated though, and this is only an example. In the real world, it gets even easier:

not_a_file_die_die_die( \@files );

You then move all the complicated stuff to a subroutine. The real trick is to make the idea and intent concise, not the code that implements the idea. The mechanics really don't matter in many cases; you care more about the result. In those cases, don't sweat the mechanics.