VHDL port mapping problem

Question

I'm relatively new to VHDL. I'm attempting to write code to do unsigned multiplication using a combination of full adders. When compiling it passes up to the port mapping. I've resolved the errors in the first map, but all of the others give me problems.

I get the same error for each: "Expression actuals in port map aspect must be static"

Here's my code. Any help is appreciated. In addition, if you have general tips based on looking at my code I would be thankful.

Thanks, Buzkie

library  ieee;
use  ieee.std_logic_1164.all;


entity fulladder is

     port (a, b, c: in std_logic;
           sout, cout: out std_logic);

     end fulladder;

architecture behav of fulladder is
begin

sout <= (a xor b) xor c ;
cout <= (a and b) or (c and (a xor b));

     end behav;

library ieee;
use ieee.std_logic_1164.all;

entity unsignedmult is 
port (a,b: in     std_logic_vector (3 downto 0);
       pro: out std_logic_vector (7 downto 0)); 

end unsignedmult;     


architecture synth of unsignedmult is

    --Declarations
    signal c1,c2,c3,c4,c5: std_logic_vector (3 downto 0);
    signal s1,s2,s3,s4: std_logic_vector (2 downto 0);
    component fulladder
        port (a,b,c:in std_logic;
           sout,cout:out std_logic);
    end component;

begin  

    --Row 0                    ----Sin-----A&B-------Cin--Sout---Cout
    Fand00: fulladder port map('0',(a(0) and b(0)),'0',pro(0),c1(0));   
    Fand01: fulladder port map('0',(a(1) and b(0)),'0',s1(0),c1(1));
    Fand02: fulladder port map('0',(a(2) and b(0)),'0',s1(1),c1(2));
    Fand03: fulladder port map('0',(a(3) and b(0)),'0',s1(2),c1(3));

    --Row 1
    Fand10: fulladder port map(s1(0),(a(0) and b(1)),c1(0),pro(1),c2(0));
    Fand11: fulladder port map(s1(1),(a(1) and b(1)),c1(1),s2(0),c2(1));
    Fand12: fulladder port map(s1(2),(a(2) and b(1)),c1(2),s2(1),c2(2));
    Fand13: fulladder port map('0',(a(3) and b(1)),c1(3),s2(2),c2(3));

    --Row 2
    Fand20: fulladder
         ----Sin------A&B------Cin-Sout-Cout
       port map(s2(0),(a(0) and b(2)),c2(0),pro(2),c3(0));
    Fand21: fulladder
         ----Sin--A&B------Cin-Sout-Cout
       port map(s2(1),(a(1) and b(2)),c2(1),s3(0),c3(1));
    Fand22: fulladder
         ----Sin--A&B------Cin-Sout-Cout
       port map(s2(2),(a(2) and b(2)),c2(2),s3(1),c3(2));
    Fand23: fulladder
         ----Sin--A&B------Cin-Sout-Cout
       port map('0',(a(3) and b(2)),c2(3),s3(2),c3(3));

    --Row 3
    Fand30: fulladder
         ----Sin------A&B------Cin-Sout-Cout
       port map(s3(0),(a(0) and b(3)),c3(0),pro(3),c4(0));
    Fand31: fulladder
         ----Sin--A&B------Cin-Sout-Cout
       port map(s3(1),(a(1) and b(3)),c3(1),s4(0),c4(1));
    Fand32: fulladder
         ----Sin--A&B------Cin-Sout-Cout
       port map(s3(2),(a(2) and b(3)),c3(2),s4(1),c4(2));
    Fand33: fulladder
         ----Sin--A&B------Cin-Sout-Cout
       port map('0',(a(3) and b(3)),c3(3),s4(2),c4(3));

    --Row 4
    F40: fulladder
       port map(s4(0),c4(0),'0',pro(4),c5(0));
    F41: fulladder
       port map(s4(1),c4(1),c5(0),pro(5),c5(1));
    F42: fulladder
       port map(s4(2),c4(2),c5(1),pro(6),c5(2));
    F43: fulladder
       port map('0',c4(3),c5(2),pro(7),c5(3));

end synth;

Answer 1

I'm rusty, but you might need to have explicit and gates for the a(_) and b(_) entries. I've heard of wire-ORs, but not wire-ANDs (in positive logic at least).

At the very least, try replacing each of these with just the a(_) portion, and see if the errors go away. It won't be the right circuit, but it will confirm if I'm right as to what's causing the compilation problem.

Answer 2

If I remember things correctly, you can't map a logic expression (e.g. a(0) and b(0)) to a port (but I think constants are OK). If this is correct, you have to create explicit signals for all inputs and outputs.

Also: 1) I don't think the fulladder architecture is behavioral, so I would name it something else. I have used (correctly or not) the name rtl for these architectures.

2) It should be possible to instantiate the full adders without declaring the component. Use a syntax like

Fand00: entity fulladder port map(...)

I also find it usual to always specify the formal port names (cout => c1(0), with some reservation for the direction of the arrow, etc.)

3) I suppose you know that any recently new synthesizer will be able to synthisize a multiplication and that you are just doing this for learning how it works, otherwise I just told you :)

Answer 3

Some synthesizers have problems with port maps that are not static expressions.

You may have to replace the expression in the port map with a signal, wherever the synthesizer complains. For example:

Fand00: fulladder port map('0',(a(0) and b(0)),'0',pro(0),c1(0));

With:

signal t: std_logic;

...

t <= a(0) and b(0);

...

Fand00: fulladder port map('0',t,'0',pro(0),c1(0));

If at all possible, change to a different synthesizer software. Don't torture yourself.