How can I append characters to a line in a file?

Question

I have a CSV file that was extracted from a ticketing system (I have no direct DB access to) and need to append a couple of columns to this from another database before creating reports off of it in Excel.

I'm using Perl to pull data out of the other database and would like to just append the additional columns to the end of each line as I process the file.

Is there a way to do this without having to basically create a new file? The basic structure is:

foreach $line (@lines) {
    my ($vars here....) = split (',',$line);
    ## get additional fields
    ## append new column data to line
}

Answer 1

Consider using the -i option to edit <> files in-place.

Answer 2

You could look at DBD::CSV to treat the file as if it were a database (which would also handle escaping special characters for you).

Answer 3

You can use Tie::File (in the Perl core since Perl 5.8) to modify a file in place:

#!/usr/bin/perl

use strict;
use warnings;

use Tie::File;


my $file = shift;

tie my @lines, "Tie::File", $file
    or die "could not open $file: $!\n";

for my $line (@lines) {
    $line .= join ",", '', get_data();
}

sub get_data {
    my $data = <DATA>;
    chomp $data;
    return split /-/, $data
}

__DATA__
1-2-3-4
5-6-7-8

You can also use in-place-editing with the @ARGV/<> trick by setting $^I:

#!/usr/bin/perl

use strict;
use warnings;

$^I = ".bak";

while (my $line = <>) {
    chomp $line;
    $line .= join ",", '', get_data();
    print "$line\n";
}

sub get_data {
    my $data = <DATA>;
    chomp $data;
    return split /-/, $data
}

__DATA__
1-2-3-4
5-6-7-8

Answer 4

Despite any nice interfaces, you have to eventually read the file line-by-line. You might even have to do more that that if some quoted fields can have embedded newlines. Use something that knows about CSV to avoid some of those problems. Text::CSV_XS should save you most of the hassle of odd cases.