while loop in batch

Question

Hello Here is what I want, inside the BACKUPDIR, I want to execute cscript /nologo c:\deletefile.vbs %BACKUPDIR% until number of files inside the folder is greater than 21(countfiles holds it). Here is my code:

@echo off
SET BACKUPDIR=C:\test
for /f %%x in ('dir %BACKUPDIR% /b ^| find /v /c "::"') do set countfiles=%%x

for %countfiles% GTR 21 (
cscript /nologo c:\deletefile.vbs %BACKUPDIR%
set /a countfiles-=%countfiles%
)

Answer 1

A while loop can be simulated in cmd.exe with:

:while1
if %countfiles% leq 21 (
    :: change countfile here
    goto :while1
)

For example, the following script:

@echo off
setlocal enableextensions enabledelayedexpansion
set /a "x = 0"
:while1
    if %x% leq 5 (
        echo %x%
        set /a "x = x + 1"
        goto :while1
    )
endlocal

outputs:

0
1
2
3
4
5

For your particular case, I would start with the following. Your initial description was a little confusing. I'm assuming you want to delete files in that directory until there's 20 or less:

@echo off
set backupdir=c:\test

:loop1
for /f %%x in ('dir %backupdir% /b ^| find /v /c "::"') do set countfiles=%%x
if %countfiles% gtr 20 (
    cscript /nologo c:\deletefile.vbs %backupdir%
    goto :loop1
)

Answer 2

set /a countfiles-=%countfiles%

This will set countfiles to 0. I think you want to decrease it by 1, so use this instead:

set /a countfiles=countfiles-1

I'm not sure if the for loop will work, better try something like this:

:loop
cscript /nologo c:\deletefile.vbs %BACKUPDIR%
set /a countfiles-=1
if %countfiles% GTR 21 goto loop