Why does this map statement in Perl not compile?

Question

This fails:

my @a = ("a", "b", "c", "d", "e");
my %h = map { "prefix-$_" => 1 } @a;

with this error:

Not enough arguments for map at foo.pl line 4, near "} @a"

but this works:

my @a = ("a", "b", "c", "d", "e");
my %h = map { "prefix-" . $_ => 1 } @a;

why?

Answer 1

Because Perl is guessing an EXPR (a hash reference, for example) instead of a BLOCK. This should work (note the '+' symbol):

my @a = ("a", "b", "c", "d", "e");
my %h = map { +"prefix-$_" => 1 } @a;

See http://perldoc.perl.org/functions/map.html.

Answer 2

From perldoc -f map:

           "{" starts both hash references and blocks, so "map { ..."
           could be either the start of map BLOCK LIST or map EXPR, LIST.
           Because perl doesn’t look ahead for the closing "}" it has to
           take a guess at which its dealing with based what it finds just
           after the "{". Usually it gets it right, but if it doesn’t it
           won’t realize something is wrong until it gets to the "}" and
           encounters the missing (or unexpected) comma. The syntax error
           will be reported close to the "}" but you’ll need to change
           something near the "{" such as using a unary "+" to give perl
           some help:

             %hash = map {  "\L$_", 1  } @array  # perl guesses EXPR.  wrong
             %hash = map { +"\L$_", 1  } @array  # perl guesses BLOCK. right
             %hash = map { ("\L$_", 1) } @array  # this also works
             %hash = map {  lc($_), 1  } @array  # as does this.
             %hash = map +( lc($_), 1 ), @array  # this is EXPR and works!
             %hash = map  ( lc($_), 1 ), @array  # evaluates to (1, @array)

           or to force an anon hash constructor use "+{"

             @hashes = map +{ lc($_), 1 }, @array # EXPR, so needs , at end

           and you get list of anonymous hashes each with only 1 entry.

Answer 3

I prefer to write that as

my %h = map { ("prefix-$_" => 1) } @a;

to show the intent, that I am returning a 2-element list.

Answer 4

Also, the other way to do what you're doing, initializing the hash, you can do like this:

my @a = qw( a b c d e );
my %h;
@h{@a} = ();

That will create undef entries for each of the five keys. If you want to give them all true values, then do this.

@h{@a} = (1) x @a;

You can also do it explicitly with a loop;

@h{$_} = 1 for @a;

Answer 5

I think that

map { ; "prefix-$_" => 1 } @a;

is more idiomatic, as far as specifying that it is a block of statements and not a hash ref. You're just kicking it off with a null statement.