Does a Perl module know where it is installed?

Question

Hi Perl programmers,

I have started creating a Perl package that contains a default email template.

The MANIFEST looks something like:

SendMyEmail.pm
SendMyEmail/defualt_email.tt

Currently I know where the module (and the template) are - but does the module itself know where on disk it is? So could the module find the default template without my help?

# This is what I would like to do.
package SendMyEmail;
sub new {
    my ($self, $template) = @_;
    $template ||= $dir_of_SendMyEmail .'/SendMyEmail/default_email.tt'; # ??
}

Is there a better way of including a templates text, or a better place to put the template?

Any references to CPAN modules that do something similar would be welcome.

Thanks in advance.

Answer 1

Rewritten to reflect what I learned in the comments:

• Find Module's Path

  package FooBar;

  use File::Spec;
  sub location {
     return File::Spec->rel2abs( FILE);
  }

• Where to put the template:
  Since the template will most likely be editable, maybe even by someone working over the net, I strongly advise putting it into a directory where the "code" contained in the template cannot be executed.
  
  Imagine someone calling: http://your.home.net/cgi-bin/default_email.tt

Answer 2

Each perl file has access to the variable __FILE__ which tells it its full path. Something like this should do the trick:

my $DEFAULT_TEMPLATE;
BEGIN {
 $DEFAULT_TEMPLATE = __FILE__;
 $DEFAULT_TEMPLATE =~ s,\.pm$,/default_email.tt,;
}

Still, if all you want is to bundle 'data' files with your modules then take a look at File::ShareDir which provides a way for doing that.

Answer 3

Perl records the file location in the %INC variable too. You can use that when __FILE__ isn't available. See the documentation in perlvar for the details.

Answer 4

You can use %INC hash if module is already loaded. For example:

## load the module
use Data::Dumper;

## output full path to Data::Dumper module loaded
print $INC{'Data/Dumper.pm'};

## see which module was loaded (if you have multiple folders with same modules)
print Dumper(\%INC);

Answer 5

You can use the __FILE__ token to get the name (including the path) of the current file. If you want to know the path to a different module (one that's already loaded) check the contents of the %INC hash.

Answer 6

Using %INC can be misleading in cases where the file does not exactly match the package name. (This is an anti-pattern, but it does happen, sometimes for justifiable reasons.) If you want to locate files, the handy __FILE__ token is your best bet. Example module that can locate itself:

package Foo::Bar;

use Cwd qw(abs_path);
use File::Basename qw(dirname);

sub module_dir { abs_path(dirname(__FILE__)) }

1;

Usage:

use Foo::Bar;

print Foo::Bar->module_dir, "\n";

Answer 7

I use this bash alias to find the location of a module (e.g. to look at its implementation or to hack in some debugging print statements):

perlwhere() {
    perl -wle'eval "require $ARGV[0]" or die; ($mod = $ARGV[0]) =~ s|::|/|g; print $INC{"${mod}.pm"}' $1
}

$ perlwhere Test::More
/usr/lib/perl5/5.8.8/Test/More.pm