How can I use hashes as arguments to subroutines in Perl?

Question

Hello,

I have a function that is doing some calculations and then passes some properties into another subroutine like so:

sub get_result {
    my $id = 1;     
    my %diet = ( result  => 28, 
                 verdict => 'EAT MORE FRUIT DUDE...'     
               );

    my %iq = ( result   => 193, 
               verdict => 'Professor Einstien'   
             );           
    print_result($id, %diet, %iq);
}

sub print_result {     
    my $id = shift;     
    my %d  = @_;     
    my %i  = @_;     

    print "IQ: $id\n";     
    print "DIET RESULT: $d{result}\n";     
    print "DIET VERDICT: $d{verdict}\n";     
    print "IQ RESULT: $i{result}\n";     
    print "IQ VERDICT: $i{verdict}\n";     
}

My problem is that the results printed in (DIET RESULT, DIET VERDICT) and (IQ SCORE, IQ RESULT) are both the same. As if variable %d and %i are being populated with the same variables. Any ideas why this is?

If I try shifting all three variables like so:

my $id = shift;     
my %d  = shift;     
my %i  = shift;

I get the following error:

Odd number of elements in hash assignment

Answer 1

When you pass an array (or hash) to a subroutine, the subroutine will get a list of the values (or key values pairs). That's why you cannot pass two arrays (or two hashes), because the subroutine won't know where the first array ends and the second one starts.

To work around this problem, you should pass in references instead:

my %hash1 = ( foo => 'bar' );
my %hash2 = ( bar => 'baz' );
subroutine( \%hash1, \%hash2 );

sub subroutine {
    my ( $hashref1, $hashref2 ) = @_;
    print $hasref1->{foo}, $hashref2->{bar};
}

PS: Apart from the conceptual problem, your code also features this:

my %d  = @_;     
my %i  = @_;

If %d and %i are both assigned the same value, it shouldn't come as a surprise when they are the same afterwards.

Answer 2

You need to pass references to the hashes, then in the subroutine extract and de-reference them. I googled "pass two hashes into a sub" and found http://www.wdvl.com/Authoring/Languages/Perl/ProPerl/properl2-3.html as the first hit.

Answer 3

When you pass in %diet and %iq, they both get flattened into the arg array, so in your print_result, %d contains all items in %diet and %iq.

To solve, use references of the %diet and %iq:

print_result($id, \%diet, \%iq);

Then in print_result:

my $id = shift;
my %d  = %{+shift};
my %i  = %{+shift};

Answer 4

use strict;
use warnings;

sub get_result {

  ...

  print_result( $id, \%diet, \%iq );
  # or
  print_result( $id, {%diet}, {%iq} );
}


sub print_result{
  my( $id, $diet_h, $iq_h ) = @_;
  my %diet = %$diet_h;
  my %iq = %$iq_h;

  ...

}

Or:

use strict;
use warnings;

sub print_result($\%\%);

sub get_result{

  ...

  print_result($id, %diet, %iq);
}

sub print_result($\%\%){
  my( $id, $diet_h, $iq_h ) = @_;
  my %diet = %$diet_h;
  my %iq = %$iq_h;

  ...

}

Answer 5

You might want to check out my book Intermediate Perl, about a third of which deals with references and how to work with them. This includes passing complex data structures into subroutines as well as other ways that references make your life easier. :)