What is the smallest program possible to parse an email message header?

Question

the homework: http://www.cs.rit.edu/~waw/networks/prob1.082.html

Ok, I am still confused why this question was asked for my data communications and networks class, but here is the question from my homework:

1. Write a computer program that reads the header on an e-mail message and deletes all lines except those that begin with

   From:, To:, Subject: and Cc:.

CONTEST -- Who can write the shortest program that does this.

So after thinking for a bit I decided that the following Perl code was as small as I could do this.

#!/usr/bin/perl

while (<>) { print "$_" if ($_ =~ m/^(To:|From:|Subject:|Cc:)/); }

All this does is act like a filter for which the only output is lines that start with From:, To:, Subject: and Cc: as specified in the question. Since there aren't any specific details I think that the above code works to at least correctly answer the question.

Now, I wonder how small a program could possibly written for this? I can understand if no one wants to post code because they think I will use it for the assignment, but I am more or less looking for suggestions and techniques that could help me write the shortest program possible.

Also, I am quite sure by shortest he is referring to actual code length. He did mention that scripting languages were the way to go so I doubt he is considering something like the overhead involved with an interpreter. This also means that he does not care which language is used.

Thanks for looking!

EDIT: Thanks for the suggestions! I had been reading questions here for quite a while, hopefully in the future I can contribute more. Also, some of the suggestions I trimmed my Perl code down to 55 bytes. I don't think we will need to deal with something like a multi-line header.

BONUS: Who can identify a good reason why this was asked in a class where we are discussing things like packet switching and client/server architectures?

EDIT2: For the record, my professor said that someone did this with something like 55 bytes. The only way I see that as being possible is if he was only asking for a simple implementation like the one above.

Answer 1

A few tips:

• print "$_" is equal to print
• while(<>) {...} can be replaced by adding -n to the options on the #! line/
• $_ =~ m// is equal to //
• You're typing four :'s where one is good enough.

Something like

#!/usr/bin/perl -n
print if /^(To|From|Subject|Cc):/;

Answer 2

Well, assuming you have your header in a string with one item per line (To:, From:, etc) named $head, then in Powershell it would be:

$head.Split("`n") | ?{$_ -match "[To|From|Subject|Cc]:"}

Answer 3

Why are you trying to get the shortest possible program first? Start with a correct solution and then edit it to you can't remove any more. Syntax and typing are not going to be the bottlenecks for a correct solution. Even if your program is longer than anyone else's, if you are the only one who does it correctly, you still win. :)

Read RFC 2822, "Internet Message Format" to see what you have to handle.

Then, look at the existing email parsing libraries that already exist to see the shenanigans that they have to handle. Once you think you have a solution because you follow the RFC, start working on all of the broken mailers.

If you are just trying to get work done, use the right tool. This is a job for formail if you just want to play with messages, but it you have to write tight code that will run on all the messages passing through your network, then something like qsmtp (the mod_perl for MTAs) might be what you want.

As far why you have to do this, what did the instructor say when you asked? You should get into the habit of specifying the desired end state and constraints for any assignment, whether in school or in a "real" job.

---

Here's a proper program to finish the task correctly. Mine's a bit long because I also read all of the emails from the source (which can be almost any common email storage format such as mbox, maildir, and so on) and I extract just the header from each message. This is only 51 characters:

 formail -s formail -c -XTo: -XFrom: -XCc: <my_inbox

If you'd rather have a Perl solution so you have a little more control over the output, here's that too:

#!/usr/bin/perl

use Email::Folder;

my $folder = Email::Folder->new($ARGV[0]);

foreach my $message ( $folder->messages )
    {
    print
     join "\n",
     map {
      my $h = $message->header( $_ );
      defined $h ? "$_: $h " : ();
      } 
     qw(From To Cc);

    print "\n\n";
    } 

Answer 4

OK, here's a multi-line matching program:

$/="";$_=<>;print$&while/^(To|From|Subject|Cc):.*\n( .*\n)*/mg

You wanted short, not pretty, right ;-)