How to add mnemonic character to a regular button in Flex? (Need that for shortcuts)

Question

How to add mnemonic character to a regular button in Flex? Show me some examples.

Answer 1

http://livedocs.adobe.com/flex/3/html/help.html?content=accessible_7.html

Answer 2

Here is an extended button component, that can help you deal with the task:

package test
{
import mx.controls.Button;
import flash.text.TextFormat;

public class ShortcutButton extends Button
{
    private static const underlineTF:TextFormat = new TextFormat(null, null, null, null, null, true);

    public function ShortcutButton()
    {
     super();
    }

    protected var shortcutPosition:int = -1;

    override public function set label(value:String):void
    {
     shortcutPosition = value.indexOf("~");
     if (shortcutPosition >= 0)
      value = value.substring(0, shortcutPosition) + value.substring(shortcutPosition + 1);
     super.label = value;
    }

    override protected function updateDisplayList(unscaledWidth:Number, unscaledHeight:Number):void
    {
     super.updateDisplayList(unscaledWidth, unscaledHeight);
     if (shortcutPosition > -1 && shortcutPosition < textField.text.length - 1)
      textField.setTextFormat(underlineTF, shortcutPosition, shortcutPosition+1);
    }
}
}

Just place "~" symbol before the symbol you want to underline to show it's a shortcut mnemonic character.

Example (you'll have to add xmlns:test="test.*" to the container component):

<test:ShortcutButton label="~Update" />